gettingStarted.ino

A Basic usage of RF24Logging on the Arduino IDE's Serial Monitor. This example accepts user input to change the log level used as a filter.

 
#include <string.h>
#include <Arduino.h>
#include <RF24Logging.h>
#include <RF24Loggers/ArduinoPrintLogger.h>
 
// Create hardware serial port log handler
ArduinoPrintLogger serialLogHandler(&Serial);
 
// Define global vendor id (it is stored in FLASH memory)
const char PROGMEM vendorID[] = "RF24LogExample";
const char PROGMEM DisableVendor[] = ""; // vendorId needs to be a flash string on AVR architecture
 
void setup()
{
  // configure serial port baudrate
  Serial.begin(115200);
  while (!Serial) {/* some boards need this */}
 
  // set maximal log level to ALL
  serialLogHandler.setLogLevel(RF24LogLevel::ALL);
  // set serial port handler
  rf24Logging.setHandler(&serialLogHandler);
 
  RF24Log_info(vendorID, "RF24Log/examples/gettingStarted%\n");
}
 
void loop()
{
  RF24Log_warn(vendorID, "Warn with error code = 0x%x%x%x%x", 222, 173, 190, 239);
  RF24Log_error(vendorID, "Error message with %s", "RAM string");
  RF24Log_info(vendorID, "Info about rounding a double value %.4D", 3.14159);
  RF24Log_debug(vendorID, "Debug precision of a double value %.4D", 2.71);
 
  RF24Log_log(RF24LogLevel::INFO + 1, vendorID, "message on sublevel INFO + 1");
  RF24Log_log(RF24LogLevel::WARN + 1, vendorID, "message on sublevel WARN + 1");
  RF24Log_log(RF24LogLevel::INFO + 7, vendorID, "message on sublevel INFO + 7");
  RF24Log_log(RF24LogLevel::ERROR - 1, vendorID, "message on sublevel ERROR - 1");
  RF24Log_log(RF24LogLevel::DEBUG + 8, vendorID, "message on sublevel DEBUG + 8");
 
  RF24Log_log(077, vendorID, "This\n\tis a multiline\n\t\tmessage that\n\tends with a\nblank line\n\n");
  RF24Log_log(75, vendorID, "%%%%This is level 0x%02x (0b%08b or%4d)%2c", 75, 75, 75, '!');
 
  // NOTE: negative numbers will look strange in binary, hexadecimal, and octal output if they aren't first casted as unsigned numbers
  RF24Log_log((uint8_t)(-0xAA), vendorID, "0x%02x is 0b%08b is %d, but can also be %hho", (uint8_t)(-0xAA), (uint8_t)(-0xAA), -0xAA, -0xAA);
 
  // NOTE: level 0 skips outputting the timestamp and level description
  RF24Log_log(0, DisableVendor, "\nEnter a log level (in octal form) to demonstrate filtering messages\n");
 
  delay(5000);
 
  uint8_t level = 0;
  if (Serial.available()) {
    char input = Serial.read();
    while (Serial.available() && input >= 48 && input < 56) {
      level <<= 3;
      level += input - 48;
      input = Serial.read();
    }
    RF24Log_log(0, DisableVendor, "Setting log level (in octal) to %o", level);
    serialLogHandler.setLogLevel(level);
  }
}